DECLARE SUB RegistrierungDrucken ()
DECLARE SUB DOSShell ()
DECLARE SUB SharewareHinweis ()
DECLARE SUB Bildschirmschoner ()
DECLARE SUB FormatiereDiskette ()
DECLARE SUB Onlinehilfe ()
DECLARE FUNCTION Dir$ (Index%)
COMMON SHARED MLine$, SLine$
DECLARE SUB newdir ()
REM $DYNAMIC
REM ------------------------
REM ' Arndt Commander V1.0 '
REM ------------------------
REM (c) 1997 by Matthias Arndt / ASM Software
REM ein Sharewareprogramm
REM
REM $INCLUDE: 'alles.inc'
col2 = 112
OPEN "ACCONFIG.DAT" FOR INPUT AS 1
INPUT #1, darstellung
INPUT #1, Drucker$
INPUT #1, MausEmpfindlichkeit
INPUT #1, Browser$
INPUT #1, Editor$
INPUT #1, Maske$
INPUT #1, Pfad$
CLOSE 1
MouseSensitivity MausEmpfindlichkeit * 6, MausEmpfindlichkeit * 6
IF darstellung <> 0 THEN
  Config.PldMnuStatus = 63
  Config.PldMnuSlkt2 = 15: Config.PldMnuLine = 63
  Config.PldMnuSlkt1 = 15: Config.PwrIptFrmCol = 31
  Config.PwrIptInnen = 31: Config.PwrIptPrompt = 31
  Config.PwrIptText = 15: Config.PwrIptSlkt = 15: col2 = 47
  Config.DlgFrmCol = 31: Config.DlgInnen = 31: Config.DlgSlkt = 15
  Config.WrtnFrm = 79: Config.WrtnFrmTyp = 2: Config.WrtnInnen = 79
END IF
MLine$ = Fill$(" Datei  Verzeichnis  Laufwerke  Zubeh”r  Konfiguration ", 80)
SLine$ = Fill$(" Arndt Commander v1.0  (c) 1997 by Matthias Arndt / ASM Software  F9:Men�s", 80)
Config.MouseFlag = Config.MouseVorhanden
DIM SHARED File$(1 TO 1700), att(1 TO 1700)
DIM SHARED merk(1 TO 1700), usermenu$(9), usercommand$(9)
DIM Men$(1 TO 5), Key$(1 TO 5), H$(1 TO 5, 1 TO 10)
Men$(1) = "markieren    Ins#™ffnen   Eingabe#Anzeigen      F3#Bearbeiten    F4#Drucken#Kopieren      F5#Umbenennen    F6#L”schen       F8#-#Beenden    Alt+X#"
Men$(2) = "erstellen             F7#l”schen#-#Dateimaske editieren#-#Markierungen l”schen#-#Wurzelverzeichnis zeigen#"
Men$(3) = "ausw„hlen#-#formatieren#"
Men$(4) = "DOS-Shell aufrufen#-#Bildschirmschoner      F10#Registrierformular drucken#Benutzermen�            F2#Benutzermen� definieren#-#Hilfesystem             F1#"
Men$(5) = "Bildschirmdarstellung#-#Suchpfade#-#Mausempfindlichkeit#-#Druckereinstellung#-#Kommandozeilenparameter#"
RESTORE
DATA "markiert Datei","™ffnet Datei/Unterverzeichnis","Zeigt Datei an","Bearbeitet Datei","Druckt aktuelle Datei","Kopiert Datei(en)","Benennt aktuelle Datei um","l”scht Datei(en)","","Beendet den Arndt Commander"
DATA "erstellt neues Unterverzeichnis","l”scht Unterverzeichnis","","editiert die Anzeigemaske","","l”scht die Checkmarks der markierten Dateien","","schaltet ins Wurzelverzeichnis zur�ck (Shortcut ð)","",""
DATA "w„hlt anderes Laufwerk","","formatiert Disketten","","","","","","",""
DATA "verzweigt in eine DOS-Shell","","aktiviert den Bildschirmschoner","druckt die Registrierkarte aus","ruft Benutzermen� auf","definiert Benutzermen�","","ruft Onlinehilfe auf","",""
DATA "„ndert Darstellung","","„ndert/definiert Suchpfade und Unterprogramme","","stellt Mausempfindlichkeit ein","","konfiguriert Druckerport"
DATA "","legt Kommandozeilenparameter f�r n„chste Applikation fest",""
FOR j = 1 TO 5
 FOR I = 1 TO 10
  READ H$(j, I)
 NEXT I
NEXT j
Key$(1) = zF9$: Key$(2) = "V": Key$(3) = "L": Key$(4) = "Z": Key$(5) = "K"
CLS
PrintF 1, 1, MLine$, Config.PldMnuLine
PrintF 1, 25, SLine$, col2
PrintF 1, 3, "Ú" + STRING$(78, "Ä") + "¿", 15
PrintF 1, 4, "³" + STRING$(78, " ") + "³", 15
PrintF 1, 23, "³" + STRING$(78, " ") + "³", 15
PrintF 1, 5, "Ã" + STRING$(78, "Ä") + "´", 15
PrintF 1, 22, "Ã" + STRING$(78, "Ä") + "´", 15
PrintF 1, 24, "À" + STRING$(78, "Ä") + "Ù", 15
PrintF 3, 3, "Â", 15: PrintF 3, 5, "Á", 15: PrintF 2, 4, "ð³", 15
FOR j = 6 TO 21
 PrintF 1, j, "³" + STRING$(78, " ") + "³", 15
 FOR I = 1 TO 3
  PrintF I * 19 + 2, j, "³", 15
  PrintF I * 19 + 2, 5, "Â", 15: PrintF I * 19 + 2, 22, "Á", 15
 NEXT I
NEXT j
PrintF 2, 23, CHR$(17) + STRING$(76, "±") + CHR$(16), 15
PrintF 1, 2, "Laufwerke: [A:] [B:] [C:] [D:] [E:] [F:] [andere]", 15
AltPfad$ = ""
offset = 0: altoffset = -1: cursor = 0: altcursor = 1
Kommandozeile$ = ""
DO
 a$ = INKEY$: MousePos mx, my, mk, -1
 IF mx > 2 AND mx < 80 AND my > 5 AND my < 22 AND mk <> 0 THEN
  ' Mausklick im Dateifenster
  nx = INT((mx - 2) / 20): ny = my - 6
  ncursor = ny * 4 + nx
  IF ncursor = cursor THEN
   IF mk = 1 THEN a$ = zReturn$ ELSE a$ = zIns$
  END IF
  cursor = ncursor
 END IF
 IF my = 23 AND mk <> 0 THEN
  IF mx = 2 THEN
   IF offset > 0 THEN offset = offset - 2: cursor = 0
  ELSE
   IF mx = 79 THEN
    offset = offset + 2: cursor = 63
   ELSE
    offset = INT((mx - 3) * 6): cursor = 0
   END IF
  END IF
 END IF
 PullDownMenue mx, my, mk, a$, MLine$, Men$(), Key$(), H$(), Menue, Befehl
 IF mx = 2 AND my = 4 AND mk = 1 THEN Menue = 2: Befehl = 8
 IF my = 2 AND mx > 11 AND mk = 1 THEN
  but = INT((mx - 11) / 5)
  IF but < 6 THEN
   Pfad$ = CHR$(but + 65) + ":\"
  ELSE
   Menue = 3: Befehl = 1
  END IF
 END IF
 SELECT CASE a$
  CASE zUp$
   cursor = cursor - 4
  CASE zDown$
   cursor = cursor + 4
  CASE zLeft$, zShTab$
   cursor = cursor - 1
  CASE zRight$, zTab$
   cursor = cursor + 1
  CASE zIns$
   Menue = 1: Befehl = 1
  CASE zHome$
   cursor = 0
  CASE zEnd$
   cursor = 63
  CASE zPgUp$
   cursor = cursor - 64
  CASE zPgDown$
   cursor = cursor + 64
  CASE zReturn$
   Menue = 1: Befehl = 2
  CASE zF1$
   Menue = 4: Befehl = 8
  CASE zF3$
   Menue = 1: Befehl = 3
  CASE zF4$
   Menue = 1: Befehl = 4
  CASE zF5$
   Menue = 1: Befehl = 6
  CASE zF6$
   Menue = 1: Befehl = 7
  CASE zF8$
   Menue = 1: Befehl = 8
  CASE zF7$
   Menue = 2: Befehl = 1
  CASE zF10$
   Menue = 4: Befehl = 3
 END SELECT
 IF (Menue = 1 AND Befehl = 1) THEN
  IF (cursor + offset * 4 + 1) <= dummy THEN
   IF att(cursor + offset * 4 + 1) <> 16 THEN
    merk(cursor + offset * 4 + 1) = 1 - merk(cursor + offset * 4 + 1)
    PrintF ((cursor MOD 4) * 19 + 3), (INT(cursor / 4) + 6), Dir$(cursor + offset * 4 + 1), 112
   END IF
  END IF
 END IF
 IF Menue = 2 AND Befehl = 1 THEN
  REDIM T$(1 TO 4)
  T$(1) = "Geben Sie den Namen des neuen"
  T$(2) = "Unterverzeichnisses ein."
  T$(3) = "Es wird im aktuellen Verzeich-"
  T$(4) = "nis erstellt."
  PowerInput 25, 8, "´ neues Unterverzeichnis Ã", T$(), 4, "(max. 8 Zeichen):", SubDir$, 9, 9, Alpha$, "<erstellen>#<abbrechen>#", LastBut
  IF LastBut = 1 AND LEN(SubDir$) > 0 THEN
   MKDIR Pfad$ + SubDir$
   CALL newdir: redraw = 1
  END IF
 END IF
 IF Menue = 2 AND Befehl = 2 THEN
  IF cursor + offset * 4 + 1 <= dummy AND att(cursor + offset * 4 + 1) = 16 AND File$(cursor + offset * 4 + 1) <> "." AND File$(cursor + offset * 4 + 1) <> ".." THEN
   REDIM T$(1 TO 5)
   T$(1) = "Soll das Unterverzeichnis"
   T$(2) = Pfad$ + File$(cursor + offset * 4 + 1)
   T$(3) = "wirklich gel”scht werden?"
   T$(4) = "Das Unterverzeichnis wird samt"
   T$(5) = "Inhalt gel”scht!"
   IF Dialog(10, 10, "´ Unterverzeichnis l”schen Ã", T$(), 5, "< ja >#<nein>#") = 1 THEN
    PushScreen 1, 1, 80, 25
    SHELL "deltree /Y " + Pfad$ + File$(cursor + offset * 4 + 1)
    PullScreen 1, 1, 80, 25
    CALL newdir: redraw = 1
   END IF
  END IF
 END IF
 IF Menue = 2 AND Befehl = 6 THEN
  FOR I = 1 TO 1700: merk(I) = 0: NEXT: redraw = 1
 END IF
 IF Menue = 2 AND Befehl = 8 THEN
  Pfad$ = LEFT$(Pfad$, 3)
 END IF
 IF Menue = 3 AND Befehl = 3 THEN
  FormatiereDiskette
 END IF
 IF Menue = 4 AND Befehl = 3 THEN CALL Bildschirmschoner
 IF Menue = 4 AND Befehl = 4 THEN
  RegistrierungDrucken
 END IF
 IF Menue = 4 AND Befehl > 4 AND Befehl < 7 THEN
  SharewareHinweis
 END IF
 IF Menue = 4 AND Befehl = 1 THEN
  DOSShell
  CALL newdir: redraw = 1
 END IF
 IF Menue = 4 AND Befehl = 8 THEN
  Onlinehilfe
 END IF
 IF (Menue = 1 AND Befehl = 2) THEN
  FileIdx = cursor + offset * 4 + 1
  IF FileIdx <= dummy THEN
   IF att(FileIdx) = 16 THEN
    IF LEFT$(File$(FileIdx), 1) = "." THEN
     FOR I = LEN(Pfad$) - 1 TO 1 STEP -1
      IF MID$(Pfad$, I, 1) = "\" THEN Pfad$ = LEFT$(Pfad$, I): EXIT FOR
     NEXT
    ELSE
     Pfad$ = Pfad$ + File$(FileIdx) + "\"
    END IF
   ELSE
    IF INSTR(File$(FileIdx), ".exe") OR INSTR(File$(FileIdx), ".com") OR INSTR(File$(FileIdx), ".bat") THEN
     ' Datei ausf�hren....
     OPEN "ACEXEC.BAT" FOR OUTPUT AS 1
     PRINT #1, "@echo off"
     PRINT #1, "cd " + LEFT$(Pfad$, LEN(Pfad$) - 1)
     PRINT #1, LEFT$(Pfad$, 2)
     File$ = File$(FileIdx)
     IF Kommandozeile$ <> "" THEN File$ = File$ + Kommandozeile$
     IF INSTR(File$(FileIdx), ".bat") THEN
      PRINT #1, "call " + File$
     ELSE
      PRINT #1, File$
     END IF
     PRINT #1, "cd " + CHR$(65 + GetDrive) + ":\" + GetPath$
     PRINT #1, CHR$(65 + GetDrive) + ":"
     CLOSE 1
     EXIT DO
    END IF
   END IF
  END IF
 END IF
 IF Menue = 1 AND Befehl = 3 THEN
  ' Datei anzeigen
  IF Browser$ <> "" THEN
   IF cursor + offset * 4 + 1 <= dummy AND att(cursor + offset * 4 + 1) <> 16 THEN
    PushScreen 1, 1, 80, 25
    CLS
    SHELL Browser$ + " " + Pfad$ + File$(cursor + offset * 4 + 1)
    a$ = INPUT$(1)
    PullScreen 1, 1, 80, 25
   END IF
  ELSE
   REDIM T$(1 TO 2)
   T$(1) = "Definieren Sie einen Browser"
   T$(2) = "um Dateien anzuzeigen."
   Warten 20, 10, " kein Browser ", T$(), 2
  END IF
 END IF
 IF Menue = 1 AND Befehl = 4 THEN
  ' Datei editieren
  IF Editor$ <> "" THEN
   IF cursor + offset * 4 + 1 <= dummy AND att(cursor + offset * 4 + 1) <> 16 THEN
    PushScreen 1, 1, 80, 25
    CLS
    SHELL Editor$ + " " + Pfad$ + File$(cursor + offset * 4 + 1)
    PullScreen 1, 1, 80, 25
   END IF
  ELSE
   REDIM T$(1 TO 2)
   T$(1) = "Definieren Sie einen externen"
   T$(2) = "ASCII-Editor."
   Warten 20, 10, " kein Editor ", T$(), 2
  END IF
 END IF
 IF Menue = 1 AND Befehl = 5 THEN
  ' Datei ausdrucken...
  IF Drucker$ <> "" THEN
   IF cursor + offset * 4 + 1 <= dummy AND att(cursor + offset * 4 + 1) <> 16 THEN
    REDIM T$(1 TO 2)
    T$(1) = "Die Datei " + Pfad$ + File$(cursor + offset * 4 + 1)
    T$(2) = "wirklich ausdrucken ?"
    wahl = Dialog(20, 10, "´ Datei drucken Ã", T$(), 2, "< Ja >#<Nein>#")
    IF wahl = 1 THEN
     PushScreen 1, 1, 80, 25
     SHELL "copy " + Pfad$ + File$(cursor + offset * 4 + 1) + " " + Drucker$
     PullScreen 1, 1, 80, 25
    END IF
   END IF
  ELSE
   REDIM T$(1 TO 3)
   T$(1) = "Der Arndt Commander ben”tigt"
   T$(2) = "einen definierten Drucker"
   T$(3) = "um drucken zu k”nnen."
   Warten 20, 10, " kein Drucker ", T$(), 3
  END IF
 END IF
 IF Menue = 1 AND Befehl > 5 AND Befehl < 9 THEN
  Selekt = 0
  FOR I = 1 TO dummy
   IF merk(I) <> 0 THEN Selekt = Selekt + 1
  NEXT I
  SELECT CASE Befehl
   CASE 6
    ' Kopieren
    IF Selekt = 0 AND att(cursor + offset * 4 + 1) <> 16 THEN
     REDIM T$(1 TO 2)
     T$(1) = "Kopieren: " + Pfad$ + File$(cursor + offset * 4 + 1)
     T$(2) = "Geben Sie bitte den Zielpfad ein:"
     PowerInput 15, 10, "´ Datei kopieren Ã", T$(), 2, "Pfad eingeben:", Zielpfad$, 80, 30, Alpha$, "<Kopieren>#<Abbrechen>#", Last
     Zielpfad$ = LTRIM$(RTRIM$(Zielpfad$))
     IF Last = 1 THEN
      PushScreen 1, 1, 80, 25
      SHELL "copy " + Pfad$ + File$(cursor + offset * 4 + 1) + " " + Zielpfad$
      PullScreen 1, 1, 80, 25
     END IF
    ELSE
     REDIM T$(1 TO 4)
     T$(1) = "Die Funktion zum Kopieren von mehreren"
     T$(2) = "Dateien ist in der Sharewareversion"
     T$(3) = "noch nicht enthalten."
     T$(4) = "Die Vollversion enth„lt diese Funktion."
     Warten 20, 10, "´ Sharewarehinweis Ã", T$(), 4
    END IF
   CASE 7
    ' Umbenennen
    IF att(cursor + offset * 4 + 1) <> 16 THEN
     REDIM T$(1 TO 3)
     T$(1) = "Alter Name: " + File$(cursor + offset * 4 + 1)
     T$(2) = "Geben Sie den neuen Namen (mit"
     T$(3) = "Erweiterung ein."
     Neu$ = ""
     PowerInput 20, 10, "´ Datei umbenennen Ã", T$(), 3, "Neuer Dateiname:", Neu$, 13, 13, Alpha$, "<Umbenennen!>#<Abbrechen>#", Last
     Neu$ = LTRIM$(RTRIM$(Neu$))
     IF Last = 1 AND Neu$ <> "" THEN
      PushScreen 1, 1, 80, 25
      SHELL "rename " + Pfad$ + File$(cursor + offset * 4 + 1) + " " + Neu$
      PullScreen 1, 1, 80, 25
      AltPfad$ = ""
     END IF
    END IF
   CASE 8
    ' l”schen
    IF Selekt = 0 AND att(cursor + offset * 4 + 1) <> 16 THEN
     REDIM T$(1 TO 3)
     T$(1) = "Wollen Sie die Datei"
     T$(2) = Pfad$ + File$(cursor + offset * 4 + 1)
     T$(3) = "wirklich l”schen ?"
     IF Dialog(20, 10, "´ Datei l”schen Ã", T$(), 3, "< ja >#<nein>#") = 1 THEN
      KILL Pfad$ + File$(cursor + offset * 4 + 1)
      AltPfad$ = ""
     END IF
    ELSE
     REDIM T$(1 TO 2)
     T$(1) = "L”schen: Sie haben " + STR$(Selekt) + " Dateien ausgew„hlt."
     T$(2) = "Wollen Sie wirklich alle l”schen ?"
     IF Dialog(20, 10, "´ Dateien l”schen Ã", T$(), 2, "< ja >#<nein>#") = 1 THEN
      PushScreen 1, 1, 80, 25
      FOR I = 1 TO dummy
       IF merk(I) <> 0 THEN
        KILL Pfad$ + File$(I)
       END IF
      NEXT I
      PullScreen 1, 1, 80, 25
      AltPfad$ = ""
     END IF
    END IF
  END SELECT
 END IF
 IF Menue = 3 AND Befehl = 1 THEN
  REDIM T$(1 TO 2)
  T$(1) = "Geben Sie bitte den Laufwerks-"
  T$(2) = "buchstaben ein."
  PowerInput 22, 10, "´ Laufwerkswahl: Ã", T$(), 2, "Laufwerksbuchstabe:", SS$, 2, 2, Alpha$, "< Ok >#<Abbrechen>#", Last
  IF Last = 1 THEN
   SS$ = LEFT$(Upper$(SS$), 1)
   IF ASC(SS$) > 64 AND ASC(SS$) < 65 + 27 THEN Pfad$ = SS$ + ":\"
  END IF
 END IF
 IF Befehl = 4 AND Menue = 2 THEN
  ' Dateimaske editieren
  REDIM T$(1 TO 2)
  T$(1) = "Geben Sie bitte die neue Dateimaske"
  T$(2) = "f�r das Dateifenster ein:"
  PowerInput 25, 12, "´ neue Dateimaske: Ã", T$(), 2, "neue Dateimaske (z.B. *.exe):", S$, 10, 10, Alpha$, "< Ok >#<Abbrechen>#", slkt%
  IF slkt% = 1 THEN
   Maske$ = S$
  END IF
  AltPfad$ = ""
 END IF
 IF (Menue = 1 AND Befehl = 10) OR a$ = zAltX$ THEN
  REDIM T$(1 TO 2)
  T$(1) = "Wollen Sie den Arndt Commander"
  T$(2) = "wirklich verlassen ?"
  IF Dialog(28, 10, "´ AC beenden Ã", T$(), 2, "< Ja >#<Nein>#") = 1 THEN EXIT DO
 END IF
 IF Menue = 5 THEN
  ' Konfigurationsmen�s des Arndt Commanders
  SELECT CASE Befehl
   CASE 1
    REDIM T$(1 TO 4)
    T$(1) = "W„hlen Sie bitte den Darstellungs-"
    T$(2) = "modus aus."
    T$(3) = "Die Žnderung ist erst nach dem"
    T$(4) = "n„chsten Neustart des AC aktiv."
    darstellung = 1 - Dialog(22, 8, "´ Bildschirmdarstellung Ã", T$(), 4, "<monochrom>#<farbig>#")
   CASE 3
    REDIM T$(1 TO 3)
    T$(1) = "Definieren Sie hier die Pfade"
    T$(2) = "und Dateinamen der zu verwen-"
    T$(3) = "denden Browser und Editoren."
    SELECT CASE Dialog(20, 10, "´ Suchpfade definieren Ã", T$(), 3, "<Browser>#<ASCII-Editor>#<Abbrechen>#")
     CASE 1
      REDIM T$(1 TO 2)
      T$(1) = "Geben Sie hier Pfad und Dateinamen"
      T$(2) = "des ASCII-Browsers an."
      AltBrowser$ = Browser$
      PowerInput 20, 5, "´ Browser festlegen Ã", T$(), 2, "Pfad & Dateinamen:", Browser$, 80, 20, Alpha$, "< Ok >#<Abbrechen>#", LastBut
      IF LastBut = 2 THEN Browser$ = AltBrowser$
     CASE 2
      REDIM T$(1 TO 2)
      T$(1) = "Geben Sie hier Pfad und Dateinamen"
      T$(2) = "des ASCII-Editors an."
      AltEditor$ = Editor$
      PowerInput 20, 5, "´ Editor festlegen Ã", T$(), 2, "Pfad & Dateinamen:", Editor$, 80, 20, Alpha$, "< Ok >#<Abbrechen>#", LastBut
      IF LastBut = 2 THEN Editor$ = AltEditor$
    END SELECT
   CASE 5
    IF Config.MouseVorhanden THEN
     REDIM T$(1 TO 2)
     T$(1) = "W„hlen Sie bitte Ihre Einstellung"
     T$(2) = "der Mausempfindlichkeit im AC aus."
     wahl = 4 - Dialog(22, 10, "´ Mausempfindlichkeit Ã", T$(), 2, "<gering>#<normal>#<hoch>#")
     MausEmpfindlichkeit = wahl
     MouseSensitivity wahl * 6, wahl * 6
    END IF
   CASE 7
    REDIM T$(1 TO 4)
    T$(1) = "W„hlen Sie bitte den benutzten "
    T$(2) = "Druckeranschluá aus."
    T$(3) = "Es werden nur parallele Drucker"
    T$(4) = "oder eine Datei akzeptiert."
    SELECT CASE Dialog(20, 8, "´ Drucker w„hlen: Ã", T$(), 4, "<LPT1>#<LPT2>#<Datei>#<keiner>#")
     CASE 1
      Drucker$ = "LPT1:"
     CASE 2
      Drucker$ = "LPT2:"
     CASE 3
      REDIM T$(1 TO 4)
      T$(1) = "Geben Sie bitte den kompletten Pfad"
      T$(2) = "und die Datei ein , in die die"
      T$(3) = "Druckerausgabe umgeleitet werden"
      T$(4) = "soll."
      PowerInput 20, 5, "´ Druckausgabe in Datei Ã", T$(), 4, "z.B. c:\TMP\AUSDRUCK.TXT", Dr$, 80, 20, Alpha$, "< Ok >#<Abbrechen>#", LastBut
      IF LastBut = 1 THEN
       Drucker$ = Dr$
      END IF
     CASE 4
      Drucker$ = ""
    END SELECT
   CASE 9
    ' Kommandozeile festlegen
    REDIM T$(1 TO 3)
    T$(1) = "Geben Sie bitte die Kommandozeilenparameter"
    T$(2) = "f�r den n„chsten Programmstart ein."
    T$(3) = "Die Parameter werden automatisch gel”scht!"
    DO
     PowerInput 16, 5, "´ Kommandozeilenparameter�bergabe Ã", T$(), 3, "(max. 127 Zeichen)", Km$, 127, 25, Alpha$, "<�bernehmen>#<l”schen>#<abbrechen>#", Last
     IF Last = 2 THEN Km$ = ""
    LOOP UNTIL Last = 1 OR Last = 3
    IF Last = 1 THEN Kommandozeile$ = Km$
    redraw = 1
  END SELECT
 END IF
 IF Pfad$ <> AltPfad$ THEN
  CALL newdir: redraw = 1
  offset = 0: cursor = 0
 END IF
 IF cursor <> altcursor THEN
  PrintF ((altcursor MOD 4) * 19 + 3), (INT(altcursor / 4) + 6), Dir$(altcursor + offset * 4 + 1), 15
  IF cursor < 0 THEN
   cursor = 0
   IF offset > 0 THEN offset = offset - 1
  END IF
  IF cursor > 63 THEN
   cursor = 63
   IF offset < dummy / 4 THEN offset = offset + 1
  END IF
  PrintF ((cursor MOD 4) * 19 + 3), (INT(cursor / 4) + 6), Dir$(cursor + offset * 4 + 1), 112
  altcursor = cursor
 END IF
 IF offset <> altoffset THEN
  PrintF 2, 23, CHR$(17) + STRING$(76, "±") + CHR$(16), 15
  PrintF 3 + (offset / 6), 23, "Û", 15
  IF offset < 0 THEN offset = 0
  IF offset > 409 THEN offset = 409
  altoffset = offset: redraw = 1
 END IF
 IF cursor <> altcursor THEN
  PrintF ((altcursor MOD 4) * 19 + 3), (INT(altcursor / 4) + 6), Dir$(altcursor + offset * 4 + 1), 15
  IF cursor < 0 THEN
   cursor = 0
   IF offset > 0 THEN offset = offset - 1
  END IF
  IF cursor > 63 THEN
   cursor = 63
   IF offset < dummy / 4 THEN offset = offset + 1
  END IF
  PrintF ((cursor MOD 4) * 19 + 3), (INT(cursor / 4) + 6), Dir$(cursor + offset * 4 + 1), 112
  altcursor = cursor
 END IF
 IF redraw <> 0 THEN
  PrintF 4, 4, STRING$(76, " "), 15
  PrintF 4, 4, Pfad$ + Maske$, 15
  IF Kommandozeile$ <> "" THEN PrintF 45, 4, "Param.:" + LEFT$(Kommandozeile$, 30), 15
  FillSpace 2, 6, 78, 16, " ", 15
  FOR j = 6 TO 21
   PrintF 1, j, "³" + STRING$(78, " ") + "³", 15
   FOR I = 1 TO 3
    PrintF I * 19 + 2, j, "³", 15
    PrintF I * 19 + 2, 5, "Â", 15: PrintF I * 19 + 2, 22, "Á", 15
   NEXT I
  NEXT j
  FOR j = 1 TO dummy
   I = (j - 1) - offset * 4
   IF I > -1 AND I < 64 THEN
    PrintF ((I MOD 4) * 19 + 3), (INT(I / 4) + 6), Dir$(j), 15
   END IF
  NEXT j
  PrintF ((cursor MOD 4) * 19 + 3), (INT(cursor / 4) + 6), Dir$(cursor + offset * 4 + 1), 112
  redraw = 0
 END IF
LOOP
OPEN "ACCONFIG.DAT" FOR OUTPUT AS 1
PRINT #1, darstellung
PRINT #1, Drucker$
PRINT #1, MausEmpfindlichkeit
PRINT #1, Browser$
PRINT #1, Editor$
PRINT #1, Maske$
PRINT #1, Pfad$
CLOSE 1
END

Registrierungsformular:
DATA "ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿"
DATA "³                         REGISTRIERUNGSFORMULAR                             ³"
DATA "³                        ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ                            ³"
DATA "³                                                                            ³"
DATA "³ Ich bestelle hiermit folgende Programme von ASM Software:                  ³"
DATA "³ (bitte ankreuzen)                                                          ³"
DATA "³                                                                            ³"
DATA "³ ASM Software Anwendungs- und Dienstprogramme:                              ³"
DATA "³                                                                            ³"
DATA "³ [ ] ARNDT COMMANDER (Vollversion)                             10 DM        ³"
DATA "³ [ ] POWER WORKS (Komplettpaket , inklusive ARNDT COMMANDER)   30 DM        ³"
DATA "³ [ ] FRAKTALSEE  (Apfelm„nnchen in 3D , ben”tigt VGA)          10 DM        ³"
DATA "³                                                                            ³"
DATA "³ ASM Software  Spielprogramme:                                              ³"
DATA "³                                                                            ³"
DATA "³ [ ] DOS QUADRAZ (Vollversion)                                 10 DM        ³"
DATA "³ [ ] ROCKS       (dito)                                        10 DM        ³"
DATA "³ [ ] POP's LABYRINTH (Public-Domain, nur Kopie & Transport)     5 DM        ³"
DATA "³                                                              -------       ³"
DATA "³                                               Bestellsumme: ____ DM        ³"
DATA "³                        Die Kaufsumme beinhaltet PORTO & VERPACKUNG!        ³"
DATA "ÃÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ´"
DATA "³ Ich arbeite mit (bitte ankreuzen) [ ] 486  [ ] Pentium  [ ] Pentium MMX    ³"
DATA "³                                   [ ] 8 MB [ ] 16 MB [ ] 32 MB [ ] ___ MB  ³"
DATA "³             RAM meiner VGA-Karte  [ ] 1 MB [ ] 2 MB  [ ] 4 MB  [ ] ___ MB  ³"
DATA "³  Ich besitze folgende Soundkarte  [ ] Soundblaster     [ ] Soundblaster Pro³"
DATA "³                                   [ ] GravisUltraSound [ ] Adlib           ³"
DATA "³                                   [ ] keine                                ³"
DATA "³                       Ich benutze [ ] DOS , Version ____  [ ] Windows 95   ³"
DATA "³                                   [ ] OS/2                [ ] Windows NT   ³"
DATA "ÃÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ´"
DATA "³ Lieferung erfolgt NUR per Nachnahme!                                       ³"
DATA "³                                                                            ³"
DATA "³ Name:_____________________________________ Firma (opt.):__________________ ³"
DATA "³ Straáe:_______________________ Hausnr.:___                                 ³"
DATA "³ PLZ:__________ Ort:_______________________ Land (opt.):___________________ ³"
DATA "³ E-mail:___________________________________                                 ³"
DATA "ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ"
DATA "  "
DATA "Oberen Teil abschneiden und an folgende Adresse senden:"
DATA " "
DATA "             Matthias Arndt"
DATA "             ASM Software"
DATA "             Im Lahbusch 2 "
DATA "          28832 Achim-Borstel"
DATA "              Deutschland "
DATA " "
DATA "Vielen Dank f�r Ihre Bestellung!"
DATA "///"

SUB Bildschirmschoner
 Showmouse 0
 PushScreen 1, 1, 80, 25
 CLS
 DO
  a$ = INKEY$
  MousePos X1, Y1, K1, -1
 LOOP UNTIL K1 <> 0 OR a$ <> ""
 DO
  a$ = INKEY$
  MousePos X1, Y1, K1, -1
 LOOP UNTIL a$ = "" AND K1 = 0
 PullScreen 1, 1, 80, 25
 Showmouse 1
END SUB

FUNCTION Dir$ (Index%)
 SHARED merk(), File$(), att()
 IF att(Index%) = 16 THEN
  att$ = " [DIR]"
 ELSE
  att$ = "      "
  IF merk(Index%) <> 0 THEN att$ = "     û"
 END IF
 Dir$ = Fill$(File$(Index%), 12) + att$
END FUNCTION

REM $STATIC
SUB DOSShell
 SHARED Pfad$
 PushScreen 1, 1, 80, 25
 CLS
 Frame 1, 1, 80, 4, "", 7, 7, 3, "", 0
 PrintF 2, 2, "Geben Sie EXIT ein , um zum Arndt Commander zur�ckzukehren...", 7
 PrintF 2, 3, "Es ist nicht empfehlenswert , von hier aus Programme zu starten!", 7
 LOCATE 5, 1
 SHELL
 PullScreen 1, 1, 80, 25
END SUB

SUB FormatiereDiskette
 SHARED Pfad$
 REDIM T$(1 TO 5)
 T$(1) = "Wollen Sie wirklich eine Diskette"
 T$(2) = "formatieren ?"
 T$(3) = "Festplatten k”nnen Sie im AC aus"
 T$(4) = "Sicherheitsgr�nden nur per Hand"
 T$(5) = "formatieren."
 IF Dialog(20, 10, "´ Diskette formatieren Ã", T$(), 5, "< Ja >#<Nein>#") = 1 THEN
  REDIM T$(1 TO 1)
  T$(1) = "W„hlen Sie das Ziellaufwerk aus."
  wahl = Dialog(20, 10, "´ Ziellaufwerk w„hlen: Ã", T$(), 1, "< A: >#< B: >#<Abbrechen>#")
  IF wahl = 3 THEN EXIT SUB
  Ziellaufwerk$ = CHR$(64 + wahl) + ":"
  REDIM T$(1 TO 4)
  T$(1) = "W„hlen Sie das Format des Laufwerks " + Ziellaufwerk$
  T$(2) = "Es werden nur Floppylaufwerke mit"
  T$(3) = "doppelter oder hoher Schreibdichte"
  T$(4) = "unterst�tzt."
  groesse = Dialog(20, 10, "´ Diskettengr”áe w„hlen: Ã", T$(), 4, "< 3« Zoll >#< 5¬ Zoll >#")
  REDIM T$(1 TO 1)
  T$(1) = "W„hlen Sie bitte die Zielkapazit„t:"
  IF groesse = 1 THEN
   Button$ = "< 720 KByte >#< 1.44 MByte >#"
  ELSE
   Button$ = "< 360 KByte >#< 1.2 MByte >#"
  END IF
  format = Dialog(20, 10, "´ Zielkapazit„t w„hlen: Ã", T$(), 1, Button$)
  REDIM T$(1 TO 2)
  T$(1) = "Geben Sie der Diskette eine"
  T$(2) = "Bezeichnung."
  PowerInput 20, 10, "´ Bezeichnung eingeben: Ã", T$(), 2, "(max. 11 Zeichen:)", Bzng$, 12, 12, Alpha$, "<�bernehmen>#<�bergehen>#", auswahl
  IF auswahl = 2 THEN Bzng$ = "AC_" + STR$(INT(RND * 152) + 1)
  FOR I = 1 TO LEN(Bzng$)
   IF MID$(Bzng$, I, 1) = " " OR MID$(Bzng$, I, 1) = "." OR MID$(Bzng$, I, 1) = ";" OR MID$(Bzng$, I, 1) = ":" OR MID$(Bzng$, I, 1) = "-" THEN
    MID$(Bzng$, I, 1) = "_"
   END IF
  NEXT I
  REDIM T$(1 TO 2)
  T$(1) = "Sollen die Systemdateien (incl. COMMAND.COM)"
  T$(2) = "auf die Diskette kopiert werden ?"
  Systemdateien = 2 - Dialog(20, 10, "´ Systemdateien kopieren ? Ã", T$(), 2, "< ja >#<nein>#")
  REDIM T$(1 TO 2)
  T$(1) = "Bitte die zu formatierende Diskette"
  T$(2) = "in Laufwerk " + Ziellaufwerk$ + " einlegen."
  IF Dialog(20, 8, "´ Formatieren best„tigen Ã", T$(), 2, "<formatieren!>#<ABBRECHEN>#") = 2 THEN EXIT SUB
  PushScreen 1, 1, 80, 25: CLS
  Shell$ = "format " + Ziellaufwerk$ + " /V:" + Bzng$
  IF Systemdateien = 1 THEN Shell$ = Shell$ + " /S"
  IF format = 1 THEN
   IF groesse = 1 THEN
    Shell$ = Shell$ + " /F:720"
   ELSE
    Shell$ = Shell$ + " /4"
   END IF
  END IF
  SHELL Shell$: ' DOS-Format ausf�hren!!!
  PullScreen 1, 1, 80, 25
 END IF
END SUB

REM $DYNAMIC
SUB newdir
 SHARED Maske$, Pfad$, AltPfad$, dummy
 IF RIGHT$(Pfad$, 1) <> "\" THEN Pfad$ = Pfad$ + "\"
 FOR I = 1 TO 1700: File$(I) = "": att(I) = 0: merk(I) = 0: NEXT I
 dummy = DirRead(Pfad$ + Maske$, 16, 1700, File$(), att())
 FOR I = 1 TO dummy
  IF att(I) = 16 THEN File$(I) = Upper$(File$(I)) ELSE File$(I) = Lower$(File$(I))
 NEXT I
 QuickSort File$(), att(), 1, dummy
 AltPfad$ = Pfad$
END SUB

REM $STATIC
SUB Onlinehilfe
 DO
  REDIM T$(1 TO 13)
  T$(1) = "ARNDT COMMANDER v1.0 Onlinehilfe"
  T$(2) = "Der ARNDT COMMANDER ist ein sehr einfach"
  T$(3) = "bedienbarer Dateimanager."
  T$(4) = "Er ist eine flexible Shell f�r Dateibe-"
  T$(5) = "arbeitungen und DOS-Befehle verschiedner"
  T$(6) = "Art."
  T$(7) = "Die semigrafische Oberfl„che arbeitet"
  T$(8) = "mit Pulldownmen�s und Dialogboxen."
  T$(9) = "Gleichzeitig h„lt sie sich an den Stan-"
  T$(10) = "dard , den PowerWorks f�r ASM Software"
  T$(11) = "produkte setzt."
  T$(12) = "Alle Grafikkarten werden unterst�tzt."
  T$(13) = "W„hlen Sie ein Hilfethema aus:"
  wahl = Dialog(20, 4, "´ Onlinehilfe Ã", T$(), 13, "<Tastatur>#<Maus>#<Shareware>#<zur�ck>#")
  IF wahl = 4 THEN EXIT DO
  SELECT CASE wahl
   CASE 1
    REDIM T$(1 TO 13)
    T$(1) = "Der Arndt Commander l„át sich komplett �ber"
    T$(2) = "Tastatur bedienen:"
    T$(3) = ""
    T$(4) = "Cursortasten - bewegen Dateiwahlbalken"
    T$(5) = "Eingabe      - Datei ausf�hren/”ffnen"
    T$(6) = "Einfg        - (un-)markiert Datei mit û"
    T$(7) = "Bild auf/ab  - Anzeige verschieben"
    T$(8) = "F9           - ”ffnet Pulldownmen�"
    T$(9) = ""
    T$(10) = "Alle wichtigen Funktionen sind �ber die"
    T$(11) = "Pulldownmen�s erreichbar."
    T$(12) = "Einige Funktionen lassen sich �ber die"
    T$(13) = "angegebenen Shortcuts (z.B. F5) ausl”sen."
    Warten 18, 5, "´ Onlinehilfe: Tastatur Ã", T$(), 13
   CASE 2
    REDIM T$(1 TO 13)
    T$(1) = "Der Arndt Commander l„át sich teilweise"
    T$(2) = "�ber eine angeschlossene und installierte"
    T$(3) = "Maus bedienen."
    T$(4) = ""
    T$(5) = "Mausklick im Hauptfenster - Datei w„hlen"
    T$(6) = "Eine schon gew„hlte Datei wird ge”ffnet/"
    T$(7) = "ausgef�hrt."
    T$(8) = "Rechte Maustaste  - (un-)markiert Datei"
    T$(9) = "Mausklick auf Men�leiste - Men� ”ffnen"
    T$(10) = "Mausklick auf Schiebeleiste - Ansicht"
    T$(11) = "verschieben"
    T$(12) = "Die Tastaturbedienung funktioniert dann"
    T$(13) = "weiterhin."
    Warten 18, 5, "´ Onlinehilfe: Maus Ã", T$(), 13
   CASE 3
    REDIM T$(1 TO 10)
    T$(1) = "Der Arndt Commander ist ein Shareware-"
    T$(2) = "programm."
    T$(3) = "D.h. sie d�rfen (und sollen) die Share-"
    T$(4) = "wareversion frei verteilen und kopieren."
    T$(5) = "Bei h„ufiger Benutzung sollten Sie das"
    T$(6) = "Programm registrieren lassen."
    T$(7) = "Die registrierte Vollversion enth„lt"
    T$(8) = "erweiterte Funktionen. Auáerdem erhalten"
    T$(9) = "Sie eine ausf�hrliche Produktbeschreibung."
    T$(10) = "Drucken Sie einfach das Bestellformular aus."
    Warten 20, 5, "´ Sharewareprinzip: Ã", T$(), 10
  END SELECT
 LOOP
END SUB

SUB RegistrierungDrucken
 SHARED Drucker$
 IF Drucker$ = "" THEN
  REDIM T$(1 TO 3)
  T$(1) = "Sie m�ssen einen Drucker definieren,"
  T$(2) = "wenn der Arndt Commander etwas drucken"
  T$(3) = "soll."
  Warten 20, 8, " kein Drucker ", T$(), 3
  EXIT SUB
 ELSE
  REDIM T$(1 TO 2)
  T$(1) = "Wollen Sie das Registrierformular"
  T$(2) = "wirklich ausdrucken ?"
  IF Dialog(20, 10, "´ Registrierformular drucken Ã", T$(), 2, "< ja >#<nein>#") = 2 THEN EXIT SUB
 END IF
 OPEN "REGIST.FRM" FOR OUTPUT AS 1
 RESTORE Registrierungsformular
 DO
  READ Text$
  IF Text$ = "///" THEN EXIT DO
  PRINT #1, Text$
 LOOP
 CLOSE #1
 PushScreen 1, 1, 80, 25
 SHELL "copy regist.frm " + Drucker$
 PullScreen 1, 1, 80, 25
 KILL "REGIST.FRM"
END SUB

SUB SharewareHinweis
 REDIM T$(1 TO 7)
 T$(1) = "Diese Funktion ist in der"
 T$(2) = "Sharewareversion des "
 T$(3) = "Arndt Commanders nicht ent-"
 T$(4) = "halten."
 T$(5) = "Bestellen Sie die Vollver-"
 T$(6) = "sion , um Zugriff darauf"
 T$(7) = "zu erhalten."
 Warten 25, 10, " Shareware ", T$(), 7
END SUB